Add links

    Tutorial

    From Resistance in Belgium
    Translate this page
    1. Introduction to SPARQL

    Using SPARQL is like being a detective in a vast archive collection. Instead of browsing through each document one by one, you use a language that allows you to instantly find the information matching your criteria with a single precise query.

    In the context of Resistance in Belgium, SPARQL makes it easier to access data on resistance members: place of birth, residence, official recognition statuses, or affiliation with a resistance organization.

    With SPARQL, you can:

    • Filter and cross-reference information;
    • Customize your searches with specific criteria;
    • Extract precise data without going through thousands of records manually;
    • Generate visualizations to better interpret your results.

    This approach gives you valuable autonomy when analyzing data from Resistance in Belgium. You can not only extract lists of names, but also identify complex connections, such as members affiliated with multiple organizations or recognized with different statuses.

    SPARQL gives you the superpower every researcher wants: ask an ultra-specific question and see the results appear in milliseconds. Of course, like any superpower, it takes some practice to master. But don’t worry! This tutorial is here to guide you and turn challenges into opportunities… Who said archive research had to be dusty?

    Ready to master the force of SPARQL? Let’s go!

    2. Strategy for Your First Queries

    Now that you have a general idea of what SPARQL is, here’s a strategy to help you start your research.

    There are tools to help write SPARQL queries, but to gain autonomy and flexibility, it’s often more effective to start from an existing query and adapt it to your specific needs.

    To help you get started, you can:

    • Check out our SPARQL query examples;
    • Use artificial intelligence tools that can generate queries based on your needs.

    This tutorial will guide you through the basics of SPARQL and help you identify the key elements to adapt an existing query successfully.

    3. The Basics of a SPARQL Query

    A SPARQL query is made up of a few essential elements. Here are the two main ones:

    • SELECT: this clause lets you choose which information to display in the results. You specify here which elements you want to see.
    • WHERE: this clause allows you to filter the data by defining precise criteria. This is where you describe the conditions the data must meet.

    📝 Simple Example

    Here is a query that extracts the first and last names of people in the database. Lines starting with # are comments to explain each part of the query. 

    SELECT ?lastName ?firstName
WHERE {
  ?person wdt:P1 wd:Q2 ;       # Selects individuals
          wdt:P3 ?lastName ;   # Retrieves the last name
          wdt:P2 ?firstName .  # Retrieves the first name
}

    Explanation of the example:

    1. SELECT ?lastName ?firstName:
      Indicates that we want to display the values of the ?lastName and ?firstName variables in the results.
    2. WHERE { ... }:
      Describes the structure and conditions of the query:
      • ?person wdt:P1 wd:Q2: selects items that are human beings (P1 = item type, Q2 = person).
      • wdt:P3 ?lastName: associates the last name with the variable ?lastName (P3).
      • wdt:P2 ?firstName: associates the first name with the variable ?firstName (P2).

    You now know the basics of all SPARQL queries. You’ll be able to adapt them to your needs by easily selecting the variables to use and by adding filters, additional columns, or advanced options.

    4. The Trick That Makes All the Difference

    When writing a SPARQL query, it can be tedious to remember numeric identifiers for municipalities, recognition statuses, or resistance organizations. Fortunately, an auto-completion feature is available to simplify the process.

    • Pro tip: Press Ctrl + Space while typing a property or a value. This allows you to search for terms in your language instead of relying on numeric identifiers.

    Example:
    If you're searching for a municipality like Anderlecht, instead of memorizing its identifier (e.g. wd:Q102), press Ctrl + Space and start typing "Anderlecht" — the editor will automatically suggest the correct identifier.

    This method helps you save time and avoid errors when entering identifiers.

    SPARQL autocomplete animation
    Auto-completion in action — Press Ctrl + Space to find the right property or value.
    5. Displaying Labels in Your Preferred Language

    When querying a Wikibase dataset with SPARQL, the results may sometimes display identifiers (e.g. Q102) instead of explicit text (e.g. Anderlecht). To make the results more readable, you can retrieve the labels (i.e., names) in the language of your choice (French, Dutch, German, or English). Simply use SERVICE wikibase:label at the end of your query to display values in your preferred language.

    How to do it?
    Add the wikibase:label service to your query. Here is a simple example that retrieves people’s names along with their place of residence, with labels displayed in French: 

    SELECT ?person ?personLabel ?residence ?residenceLabel
WHERE {
  ?person wdt:P1 wd:Q2 .              # Select human entities
  ?person wdt:P7 wd:Q102 .            # Residence (P7) = Anderlecht (Q102)
  SERVICE wikibase:label {            # Service to retrieve labels
    bd:serviceParam wikibase:language "fr" . # Language preference: French
  }
}

    Quick explanation

    • SERVICE wikibase:label: activates the label retrieval service.
    • bd:serviceParam wikibase:language "fr": sets the label language (replace "fr" with "en", "nl", "de", etc. as needed).

    Using AUTO_LANGUAGE
    To automatically show labels in the language set by your browser or user preferences, use AUTO_LANGUAGE: 

    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".

    Tips

    • To automatically display labels in your browser or user’s preferred language, use: bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en"
    • You can also prioritize multiple languages. For example, to display labels in French and fall back to English if unavailable: bd:serviceParam wikibase:language "fr,en,[AUTO_LANGUAGE]"
    6. Adding Additional Information

    To enrich your results, you can add multiple columns containing additional information, such as residence, date of birth, or other relevant details. To get inspired: check out the list of properties or see how data is modeled using an example, like Andrée De Jongh.

    Adding simple columns
    Just include the properties that correspond to the information you want to extract.

    Example: Add the residence and date of birth of individuals. 

    SELECT ?person ?personLabel ?residenceLabel ?birthDate
WHERE {
  ?person wdt:P7 ?residence .        # P7: Residence
  ?person wdt:P67 ?birthDate .       # P67: Date of birth

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr" }
}

    Making a column optional with OPTIONAL
    If some information might be missing, use OPTIONAL to avoid limiting the results. Adding OPTIONAL lets you retrieve results even if a column is empty.

    Example: Add date of birth only if the information is available. 

    SELECT ?person ?personLabel ?residenceLabel ?birthDate
WHERE {
  ?person wdt:P7 ?residence .        # P7: Residence

  OPTIONAL { ?person wdt:P67 ?birthDate . }  # P67: Optional date of birth

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr" }
}

    Tip: To combine multiple values into a single column (for example, to “concatenate” membership in multiple resistance organizations), use CONCAT. This allows grouping the data into a single cell while keeping one result row per person. To explore this function and its variants, refer to the SPARQL documentation available online.

    7. Limiting the Number of Results

    To reduce the number of results displayed (especially if you’re testing a query with many columns), add the LIMIT clause to your query.

    Example: Show only the first 10 results. 

    SELECT ?person ?personLabel ?birthDate
WHERE {
  ?person wdt:P67 ?birthDate .

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr"
  }
}
LIMIT 10
    8. Sorting the Results

    To sort results by a specific column, use the ORDER BY clause. By default, the sorting is ascending (ASC), but you can also specify descending order using DESC.

    Example: Sort results by birth date in ascending order. 

    SELECT ?person ?personLabel ?birthDate
WHERE {
  ?person wdt:P67 ?birthDate .

  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr"
  }
}
ORDER BY ASC(?birthDate)
    9. Adding Filters

    Filters allow you to refine your results by adding specific criteria to your query. They are useful for combining multiple conditions or excluding certain values.

    📝 Simple example without filter

    To select individuals matching a basic criterion—like “residing in Anderlecht”—you can write: 

    ?person wdt:P4 wd:Q102 .  # Selects individuals residing in Anderlecht

    Using FILTER for specific conditions
    If you want to narrow your results even more, use FILTER. This allows you to combine multiple conditions. For example: select individuals living in Anderlecht and born after January 1st, 1920 (Link to test the query). 

    SELECT ?person ?personLabel ?residenceLabel ?birthDate
WHERE {
  # Select residence and birth date of the person
  ?person wdt:P7 ?residence .        # P7: Residence
  ?person wdt:P67 ?birthDate .       # P67: Date of birth

  # Filter for people living in Anderlecht (wd:Q102) and born after Jan 1, 1920
  FILTER(?residence = wd:Q102 && ?birthDate >= "1920-01-01T00:00:00Z"^^xsd:dateTime)

  # Use the label service for readable output
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr"
  }
}

    Advanced usage: It’s also possible to use FILTER NOT EXISTS for more complex exclusions. This allows you to filter out results that meet a specific condition. You can explore this functionality further in advanced SPARQL resources.

    10. Visualizing Your Results

    To create charts from your SPARQL queries, you have two options:

    • Use the features of the Query Service: visualize the data in the form of tables, maps, bar charts, and timelines. For more details, see the Wikidata documentation.
    • Export the data and use other tools: you can export your results in CSV or TSV format, and then process them with data visualization tools.
    11. Federated Queries

    Advanced feature: If you want to query multiple databases at once to enrich your results, you can use federated queries. For an example, see this sample query, which extracts information from Resistance in Belgium and combines it with data from external sources (e.g., Wikidata).

    12. Saving and Sharing Your Queries

    After running a SPARQL query, you can save and share its link. Click the “Link” tab above the results to generate a Tiny URL (a short link) that’s easy to copy and share. This allows others to run the same query directly, with no extra effort.

    13. Downloading the Results

    After executing a query, use the “Download” tab (located on the right above the results) to export the data in different formats: CSV (compatible with LibreOffice Calc or Excel), TSV, or JSON.

    Best practice: Save the file with a clear name that reflects your search criteria to make it easier to reuse later.

    14. Additional Resources

    To deepen your knowledge and create more advanced queries, here are some useful resources:

    External Resources
    We also encourage you to consult external resources, such as Wikidata tutorials, which offer excellent introductions to SPARQL queries. Although these examples use the same software (Wikibase) as this project, note that the data and query structure are specific to Wikidata and do not apply directly to the content of Resistance in Belgium.

    Retrieved from "https://data.arch.be/w/index.php?title=Tutorial/en&oldid=217858"