Project:SPARQL/examples

Exemples de requêtes SPARQL

Cette page liste des exemples de requêtes SPARQL permettant d'interroger en profondeur les données de Resistance in Belgium voir aussi cette page d'exemples plus détaillée. Chaque requête peut être lancée en cliquant sur le lien "Try it!" qui ouvre une interface de requête dédiée.

Search for resistance fighters by family name

# This query has been automatically translated for pragmatic reasons and due to limited resources. Please be aware that some terms may not be fully accurate.

# This query retrieves the list of people present in the database with a certain last name.

#title: Resistance fighters with a certain last name (here: Barbieux)

SELECT ?person ?personLabel ?birthDate
WHERE {
  ?person  wdt:P1  wd:Q2 .                    # Selects all elements thaat are (P1) persons (Q2)
  ?person  wdt:P3  "Barbieux" .               # Filters to take only persons whose last name (P3) is "Barbieux" (modify "Barbieux" as needed)
  ?person  wdt:P67 ?birthDate  .              # Adds the birth date (P67)
           
 SERVICE wikibase:label { bd:serviceParam wikibase:language "en,[AUTO_LANGUAGE]". }  # Retrieves the label in English
}

ORDER BY ?personLabel  # Sorts the results alphabetically by label

Try it!

Recherche des membres d'une organisation de résistance

# Cette requête récupère la liste des personnes présentes dans la base de données et dont on sait qu'elles appartenaient à une certaine organisation de résistance (ici : Tempo)

#title: Résistant⸱e⸱s membres d'une organisation de résistance (ici : Tempo)

SELECT ?personne ?personneLabel ?dateNaissance
WHERE {
  ?personne  wdt:P1  wd:Q2 .                  # Sélectionne tous les éléments qui sont (P1) des personnes (Q2)
  ?personne wdt:P52 wd:Q4367 .                    # Filtre par appartenance à une organisation ("membre de", P52), ici "Tempo" (Q4367) (remplacez Q4367 par l'organisation de votre choix en utilisant l'auto-complétion (Control + espace))
  ?personne  wdt:P67 ?dateNaissance  .        # Ajoute la date de naissance (P67)
           
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }  # Récupère le libellé en français
}

Try it!

Recherche par domicile

# Cette requête récupère la liste des personnes présentes dans la base de données et domiciliées dans une certaine commune pendant/au lendemain de la Seconde Guerre mondiale

#title: Résistant⸱e⸱s filtrés selon leur domicile (ici : Anderlecht)

SELECT ?personne ?personneLabel ?dateNaissance
WHERE {
  ?personne  wdt:P1  wd:Q2 .                  # Sélectionne tous les éléments qui sont (P1) des personnes (Q2)
  ?personne  wdt:P7  wd:Q102 .                    # Filtre par domicile (P7), ici Anderlecht (Q102) (remplacez Q102 par la (section de) commune de votre choix en utilisant l'auto-complétion (Control + espace))
  ?personne  wdt:P67 ?dateNaissance  .        # Ajoute la date de naissance (P67)
           
 SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }  # Récupère le libellé en français
}

Try it!

Recherche par profession

# Cette requête récupère la liste des personnes présentes dans la base de données ayant une certaine profession (ici : coiffeur / kapper).

#title: Résistant⸱e⸱s ayant une certaine profession (ici : coiffeur / kapper)

SELECT ?personne ?personneLabel ?domicileLabel ?professionLabel
WHERE {
  ?personne  wdt:P1  wd:Q2 .               # Sélectionne toutes les personnes (P1) avec l'identifiant "Personne" (Q2)
  ?personne wdt:P13 ?profession .          # Sélectionne leur profession (P13)
  
  FILTER (CONTAINS(str(?profession), 'coiffeu')

Try it!

Nombre de membres des organisations de résistance

# Cette requête récupère le nombre de membres par organisation de résistance et affiche les résultats sous forme de graphique à bulles
# Vous pouvez cliquer sur chaque bulle ou nom d'organisation pour accéder à plus de détails sur l'organisation dans la base de données.

#title: Décompte des membres par organisation de résistance

#defaultView:BubbleChart  # Affichage sous forme de bulles

SELECT ?organisation ?organisationLabel (COUNT(?personne) AS ?nombreMembres)
WHERE {
  ?personne wdt:P1 wd:Q2 .              # Sélectionne tous les éléments qui sont (P1) des personnes (Q2)
  ?personne wdt:P52 ?organisation .     # Filtre par appartenance à une organisation ("membre de", P52)

  FILTER EXISTS { 
   ?organisation wdt:P1/wdt:P9* wd:Q4  # Vérifie si l'organisation est (P1)/est une sous-classe (P9) d'une organisation de résistance (Q4)
   }
   # Pour filtrer et afficher uniquement les réseaux/missions de résistance, remplacez Q4 par Q38.
   # Pour filtrer et afficher uniquement les mouvements de résistance armée, remplacez Q4 par Q37.

  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }  # Récupère les libellés en français
}
GROUP BY ?organisation ?organisationLabel
ORDER BY DESC(?nombreMembres)

Try it!

Lieux de décès pendant la guerre

# Cette requête récupère les lieux de décès des résistant⸱e⸱s jusqu'à la fin de l'année 1945 et les affiche sur une carte avec leur nom et, si disponible, les dates de décès
# Vous pouvez cliquer sur les points sur la carte pour afficher les noms des personnes décédées.
# Note : les lieux à l'étranger ont été "modernisés" pour correspondre aux données actuelles de la base Geonames.

#title: Lieux et dates de décès pendant la guerre

#defaultView:Map{"hide":"?GPS"}  # Affichage sous forme de carte

SELECT ?personne ?personneLabel ?lieuDecesLabel ?GPS ?dateDeces
WHERE {
  ?personne wdt:P1 wd:Q2 .                      # Sélectionne toutes les personnes (P1 = Q2)
  ?personne wdt:P48 ?lieuDeces .                # Récupère les lieux de décès (P48)
  ?lieuDeces wdt:P6 ?GPS .                      # Récupère les coordonnées GPS des lieux de décès (P6)
  OPTIONAL { ?personne wdt:P68 ?dateDeces .     # Récupère la date de décès, si disponible
             FILTER(?dateDeces <= "1945-12-31"^^xsd:dateTime)  # Filtre les décès jusqu'à fin 1945
  }
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr". }  # Récupère les libellés en français
}

Try it!