Project:SPARQL/examples/nl

SPARQL zoekopdracht voorbeelden

Deze pagina geeft voorbeelden van SPARQL-query's die het mogelijk maken om de gegevens van Resistance in Belgium diepgaand te doorzoeken (zie ook deze voorbeeldpagina). Elke query kan worden uitgevoerd door te klikken op de link "Probeer het!", die een speciale query-interface opent.

Opmerking: Om praktische redenen zijn de query's automatisch vertaald in het Engels, Nederlands en Duits. Hoewel er kleine onnauwkeurigheden kunnen zijn, hebben we prioriteit gegeven aan het beschikbaar stellen van deze voorbeelden in meerdere talen om brede toegang tot de gegevens voor alle gebruikers te waarborgen.

Verzetsmensen opzoeken op familienaam

# Deze query is automatisch vertaald om pragmatische redenen en vanwege beperkte middelen. Houd er rekening mee dat sommige termen mogelijk niet volledig nauwkeurig zijn.

# Deze query haalt de lijst op van personen in de database met een bepaalde achternaam.

#title: Verzetsstrijders met een bepaalde achternaam (hier: Barbieux)

SELECT ?persoon ?persoonLabel ?geboorteDatum
WHERE {
  ?persoon  wdt:P1  wd:Q2 .                    # Selecteert alle elementen die (P1) personen (Q2) zijn
  ?persoon  wdt:P3  "Barbieux" .               # Filtert om alleen personen te nemen waarvan de achternaam (P3) "Barbieux" is (pas "Barbieux" aan indien nodig)
  ?persoon  wdt:P67 ?geboorteDatum  .          # Voegt de geboortedatum toe (P67)
           
 SERVICE wikibase:label { bd:serviceParam wikibase:language "nl [AUTO_LANGUAGE]". } # Haalt het label in het Nederlands op
}

ORDER BY ?persoonLabel  # Sorteert de resultaten alfabetisch op label

Probeer het!

Zoeken op de leden van een bepaalde verzetsbeweging

# Deze query is automatisch vertaald om pragmatische redenen en vanwege beperkte middelen. Houd er rekening mee dat sommige termen mogelijk niet volledig nauwkeurig zijn.

# Deze query haalt de lijst op van personen in de database 
# waarvan bekend is dat ze lid waren van een bepaalde verzetsorganisatie (hier: Tempo)

#title: Verzetsstrijders die lid zijn van een verzetsorganisatie (hier: Tempo)

SELECT  ?persoon ?achternaam ?voornaam ?geboorteDatum
WHERE {
  ?persoon  wdt:P1  wd:Q2 .                   # Selecteert alle elementen die (P1) personen (Q2) zijn
  ?persoon wdt:P52 wd:Q4367 .                 # Filtert op lidmaatschap van een organisatie ("lid van", P52), hier "Tempo" (Q4367) (vervang Q4367 door de organisatie van uw keuze met behulp van autocomplete (Ctrl + spatie))
  ?persoon  wdt:P67 ?geboorteDatum  .         # Voegt de geboortedatum toe (P67)
  ?persoon  wdt:P3 ?achternaam .              # Haalt de achternaam op (P3)
  ?persoon  wdt:P2 ?voornaam .                # Haalt de voornaam op (P2)
          
 SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,[AUTO_LANGUAGE]". }  # Haalt het label in het Nederlands op
}

ORDER BY LCASE(?achternaam) LCASE(?voornaam)  # Sorteert de resultaten op achternaam, daarna voornaam (hoofdletterongevoelig)

Probeer het!

Verzetsmensen zoeken op woonplaats

# Deze query is automatisch vertaald om pragmatische redenen en vanwege beperkte middelen. Houd er rekening mee dat sommige termen mogelijk niet volledig nauwkeurig zijn.

# Deze query haalt de lijst op van personen in de database 
# die tijdens/na de Tweede Wereldoorlog in een bepaalde gemeente woonden

#title: Verzetsstrijders gefilterd op woonplaats (hier: Anderlecht)

SELECT ?persoon ?achternaam ?voornaam ?geboorteDatum
WHERE {
  ?persoon  wdt:P1  wd:Q2 .                   # Selecteert alle elementen die (P1) personen (Q2) zijn
  ?persoon  wdt:P7  wd:Q102 .                 # Filtert op woonplaats (P7), hier Anderlecht (Q102) (vervang Q102 door de (deel-)gemeente van uw keuze met behulp van autocomplete (Ctrl + spatie))
  ?persoon  wdt:P67 ?geboorteDatum  .         # Voegt de geboortedatum toe (P67)
  ?persoon  wdt:P3 ?achternaam .              # Haalt de achternaam op (P3)
  ?persoon  wdt:P2 ?voornaam .                # Haalt de voornaam op (P2)
         
 SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,[AUTO_LANGUAGE]". }  # Haalt het label in het Nederlands op
}

ORDER BY LCASE(?achternaam) LCASE(?voornaam)  # Sorteert de resultaten op achternaam, daarna voornaam (hoofdletterongevoelig)

Probeer het!

Verzetsmensen opzoeken per beroep

# Deze query is automatisch vertaald om pragmatische redenen en vanwege beperkte middelen. Houd er rekening mee dat sommige termen mogelijk niet volledig nauwkeurig zijn.

# Deze query haalt de lijst op van personen in de database met een bepaald beroep (hier: kapper / kapster).

#title: Verzetsstrijders met een bepaald beroep (hier: kapper / kapster)

SELECT ?persoon ?achternaam ?voornaam ?woonplaatsLabel ?beroepLabel
WHERE {
  ?persoon  wdt:P1  wd:Q2 .               # Selecteert alle personen (P1) met de identificatie "Persoon" (Q2)
  ?persoon  wdt:P13 ?beroep .             # Selecteert hun beroep (P13)
  ?persoon  wdt:P3 ?achternaam .          # Haalt de achternaam op (P3)
  ?persoon  wdt:P2 ?voornaam .            # Haalt de voornaam op (P2)
  
  FILTER (CONTAINS(str(?beroep), 'coiffeu')

Probeer het!

Aantal leden per verzetsbeweging

# Deze query is automatisch vertaald om pragmatische redenen en vanwege beperkte middelen. Houd er rekening mee dat sommige termen mogelijk niet volledig nauwkeurig zijn.

# Deze query haalt het aantal leden per verzetsorganisatie op en toont de resultaten als een bellenkaart.
# U kunt op elke bel of organisatienaam klikken om meer details over de organisatie in de database te zien.

#title: Aantal leden per verzetsorganisatie

#defaultView:BubbleChart  # Weergeven als bellen

SELECT ?organisatie ?organisatieLabel (COUNT(?persoon) AS ?aantalLeden)
WHERE {
  ?persoon wdt:P1 wd:Q2 .              # Selecteert alle elementen die (P1) personen (Q2) zijn
  ?persoon wdt:P52 ?organisatie .     # Filtert op lidmaatschap van een organisatie ("lid van", P52)

  FILTER EXISTS { 
   ?organisatie wdt:P1/wdt:P9* wd:Q4  # Controleert of de organisatie (P1) / een subklasse (P9) is van een verzetsorganisatie (Q4)
   }
   # Om alleen verzetsnetwerken/missies te filteren en weer te geven, vervang Q4 door Q38.
   # Om alleen gewapende verzetsbewegingen te filteren en weer te geven, vervang Q4 door Q37.

  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],nl". }  # Haalt de labels in het Nederlands op
}
GROUP BY ?organisatie ?organisatieLabel
ORDER BY DESC(?aantalLeden)

Probeer het!

De plaats van overlijden tijdens de oorlog visualiseren

# Deze query is automatisch vertaald om pragmatische redenen en vanwege beperkte middelen. Houd er rekening mee dat sommige termen mogelijk niet volledig nauwkeurig zijn.

# Deze query haalt de overlijdensplaatsen van verzetsstrijders tot het einde van 1945 op 
# en toont ze op een kaart met hun namen en, indien beschikbaar, de overlijdensdata.

# Tip: U kunt op de punten op de kaart klikken om de namen van de overleden personen te bekijken.
# Opmerking: Buitenlandse locaties zijn "gemoderniseerd" om overeen te komen met de huidige gegevens in de Geonames-database.

#title: Plaatsen en data van overlijden tijdens de oorlog

#defaultView:Map{"hide":"?GPS"}  # Weergeven als kaart, GPS-coördinaten verbergen

SELECT ?persoon ?persoonLabel ?overlijdensplaats ?overlijdensplaatsLabel ?GPS ?overlijdensDatum
WHERE {
  ?persoon wdt:P1 wd:Q2 .                      # Selecteert alle personen (P1 = Q2)
  ?persoon wdt:P48 ?overlijdensplaats .        # Haalt de overlijdensplaatsen op (P48)
  ?overlijdensplaats wdt:P6 ?GPS .             # Haalt de GPS-coördinaten van de overlijdensplaatsen op (P6)
  OPTIONAL { ?persoon wdt:P68 ?overlijdensDatum .   # Haalt de overlijdensdatum op, indien beschikbaar
             FILTER(?overlijdensDatum <= "1945-12-31"^^xsd:dateTime)  # Filtert overlijdensgevallen: tot het einde van 1945
  }
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,[AUTO_LANGUAGE]". }  # Haalt de labels in het Nederlands op
}

ORDER BY ?overlijdensplaatsLabel

Probeer het!

Alle vrouwen opgeven die aangehouden werden met, voor zover bekend, hun beroep en erkenningsstatuut

# Deze query is automatisch vertaald om pragmatische redenen en vanwege beperkte middelen. Houd er rekening mee dat sommige termen mogelijk niet volledig nauwkeurig zijn.

#title: Vrouwelijke verzetsstrijders die gevangen werden genomen
SELECT DISTINCT ?persoon ?achternaam ?voornaam ?beginVanDetentie ?eindeVanDetentie ?beroepLabel ?erkenningsstatusLabel
WHERE {

    ?persoon wdt:P1 wd:Q2 .                   # Selecteert personen (P1 = Q2)
  ?persoon wdt:P4 wd:Q6 .                   # Filtert om vrouwen te selecteren (P4 = vrouw Q6)
  
  ?persoon p:P53 ?detentie_statement .      # Zoekt naar personen die gevangen werden genomen (P53)
  ?detentie_statement ps:P53 ?detentie .
           
  OPTIONAL { ?detentie_statement pq:P23 ?beginVanDetentie. FILTER (datatype(?beginVanDetentie) = xsd:edtf ) } # Haalt de begindatum van de detentie op, indien beschikbaar (P23)
  OPTIONAL { ?detentie_statement pq:P25 ?eindeVanDetentie. FILTER (datatype(?eindeVanDetentie) = xsd:edtf ) } # Haalt de einddatum van de detentie op, indien beschikbaar (P25)

   OPTIONAL { ?persoon wdt:P13 ?beroep. }               # Haalt het beroep op, indien beschikbaar (P13)
  OPTIONAL { ?persoon wdt:P55 ?erkenningsstatus. }     # Haalt de erkenningsstatus op, indien verkregen (P55)

   ?persoon  wdt:P3 ?achternaam .           # Haalt de achternaam op (P3)
  ?persoon  wdt:P2 ?voornaam .             # Haalt de voornaam op (P2)
  
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,[AUTO_LANGUAGE]". }  # Haalt de labels in het Nederlands op

}

ORDER BY LCASE(?achternaam) LCASE(?voornaam)  # Sorteert zonder hoofdlettergevoeligheid

Probeer het!

Alle verzetsmensen opgeven die als ARA/FFC erkend werden of een bedankingsbrief kregen, met hun woonplaats en de referentie van hun persoonsdossiers

# Deze query is automatisch vertaald om pragmatische redenen en vanwege beperkte middelen. Houd er rekening mee dat sommige termen mogelijk niet volledig nauwkeurig zijn.

# Deze query haalt de lijst op van verzetsstrijders die erkend zijn als inlichtingen- en actieagenten (ARA)
# of een bedankbrief (LR) of FFC-status (Forces Françaises Combattantes) hebben ontvangen, samen met hun woonplaats en gekoppeld archiefbestand.

#title: ARA verzetsstrijders (erkend of bedankbrief) of FFC

SELECT DISTINCT ?persoon ?achternaam ?voornaam ?woonplaats ?woonplaatsLabel ?erkendeStatusLabel ?LR ?archiefCollectieLabel ?inventarisNr WHERE {

  ?persoon wdt:P1 wd:Q2 .                    # Selecteert personen (P1 = Q2)
  ?persoon  wdt:P3 ?achternaam .             # Haalt de achternaam op (P3)
  ?persoon  wdt:P2 ?voornaam .               # Haalt de voornaam op (P2)

  { ?persoon wdt:P55 ?erkendeStatus. 
    FILTER(?erkendeStatus IN (wd:Q17, wd:Q4487)) }  # Filtert op erkende ARA-statussen (Q17) of FFC (Q4487)
  UNION                                            # OF
  { ?persoon p:P54 ?statement.
    ?statement ps:P54 wd:Q17; pq:P56 wd:Q6665.     # Personen die een bedankbrief (Q6665) hebben ontvangen
    BIND("bedankbrief ARA" AS ?LR)}

  OPTIONAL { ?persoon wdt:P7 ?woonplaats. }         # Haalt de woonplaats op, indien beschikbaar (P7)
  OPTIONAL { ?persoon p:P34 ?archief_statement . 
             ?archief_statement ps:P34 ?archiefCollectie ;
                                pq:P35 ?inventarisNr.}  # Verwijzing naar de archieven
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],nl". }  # Haalt de labels in het Nederlands op
}

ORDER BY LCASE(?achternaam) LCASE(?voornaam)  # Sorteert de resultaten op achternaam, daarna voornaam (hoofdletterongevoelig)
LIMIT 100  # Beperkt de resultaten tot 100 om de prestaties te optimaliseren. U kunt deze limiet naar behoefte aanpassen of verwijderen.

Probeer het!

De gegevens over de verzetsmensen via externe bronnen verrijken [gegroepeerde opzoeking]

# Deze query is automatisch vertaald om pragmatische redenen en vanwege beperkte middelen. Houd er rekening mee dat sommige termen mogelijk niet volledig nauwkeurig zijn.

# Deze query haalt aanvullende informatie op over verzetsstrijders in de database, dankzij Wikidata, inclusief Wikipedia-artikelen en externe archieven (ODIS, Biographie Nationale, VIAF, SNAC, enz.).

#title: Verrijking van de gegevens van verzetsstrijders via Wikidata

PREFIX wd_wikidata: <http://www.wikidata.org/entity/>  # Prefix voor Wikidata
PREFIX wdt_wikidata: <http://www.wikidata.org/prop/direct/>  # Prefix voor directe eigenschappen van Wikidata

SELECT DISTINCT ?persoon ?achternaam ?voornaam ?wikidata_ID ?article_nl ?odisURL ?bioNationaleURL ?JusteURL ?maitronURL ?viafURL ?snacURL 
(GROUP_CONCAT(DISTINCT ?archivesLabel; SEPARATOR = ", ") AS ?archives)  # Samenvoeging van de gevonden archieven

WHERE {
  ?persoon wdt:P1 wd:Q2 .                  # Selecteert alle personen (P1 = Q2)
  ?persoon  wdt:P3 ?achternaam .           # Haalt de achternaam op (P3)
  ?persoon  wdt:P2 ?voornaam .             # Haalt de voornaam op (P2)

    ?persoon wdt:P15 ?wikidataIdentifier .   # Haalt de Wikidata-ID op (P15)

   # Genereert een link naar het overeenkomstige Wikidata-item
  BIND(URI(CONCAT("http://www.wikidata.org/entity/", ?wikidataIdentifier)) AS ?wikidata_ID)

  # Gefedereerde query om aanvullende informatie van Wikidata op te halen
  SERVICE <https://query.wikidata.org/sparql> {
    
    # Haalt de URL's van externe identificaties op en genereert deze
    OPTIONAL { 
      ?wikidata_ID wdt_wikidata:P2372 ?odisID.  # Haalt de ODIS-ID op
      BIND(URI(CONCAT("https://www.odis.be/lnk/", STR(?odisID))) AS ?odisURL)  # Genereert de ODIS-URL
    }
    OPTIONAL { 
      ?wikidata_ID wdt_wikidata:P6234 ?bioNationaleID.  # Biographie Nationale van België ID
      BIND(URI(CONCAT("https://academieroyale.be/fr/la-biographie-nationale-personnalites-detail/personnalites/", STR(?bioNationaleID), "/Vrai/")) AS ?bioNationaleURL)  # Genereert de Biographie Nationale-URL
    }
    OPTIONAL { 
      ?wikidata_ID wdt_wikidata:P214 ?viafID.  # VIAF-ID
      BIND(URI(CONCAT("https://viaf.org/viaf/", STR(?viafID))) AS ?viafURL)  # Genereert de VIAF-URL
    }
    OPTIONAL { 
      ?wikidata_ID wdt_wikidata:P3430 ?snacID.  # SNAC-ID
      BIND(URI(CONCAT("https://snaccooperative.org/ark:/99166/", STR(?snacID))) AS ?snacURL)  # Genereert de SNAC-URL
    }
    OPTIONAL { 
      ?wikidata_ID wdt_wikidata:P4724 ?maitronID.  # Maitron-ID
      BIND(URI(CONCAT("https://maitron.fr/spip.php?article", STR(?maitronID))) AS ?maitronURL)  # Genereert de Maitron-URL
    }
    OPTIONAL { 
      ?wikidata_ID wdt_wikidata:P1979 ?JusteID.  # Rechtvaardige onder de Naties ID
      BIND(URI(CONCAT("https://collections.yadvashem.org/en/righteous/", STR(?JusteID))) AS ?JusteURL)  # Genereert de Rechtvaardige onder de Naties-URL
    }
    
    # Haalt het Nederlandstalige Wikipedia-artikel op
    OPTIONAL {
      ?article_nl schema:about ?wikidata_ID ;
                  schema:inLanguage "nl" ;
                  schema:isPartOf <https://nl.wikipedia.org/> .  # Nederlandstalig Wikipedia-artikel
    }
    
    # Haalt de archieven op die aan de persoon zijn gekoppeld
    OPTIONAL {
      ?wikidata_ID wdt_wikidata:P485 ?archives.  # Haalt archieven op (P485)
      ?archives rdfs:label ?archivesLabel.  # Haalt archieflabels op
      FILTER(LANG(?archivesLabel) = "nl")  # Filtert op labels in het Nederlands
    }
  }

   # Haalt de labels van personen op in de gedefinieerde taal
  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],nl". }
}

GROUP BY ?persoon ?achternaam ?voornaam ?wikidata_ID ?article_nl ?odisURL ?JusteURL ?bioNationaleURL ?maitronURL ?viafURL ?snacURL

ORDER BY LCASE(?achternaam) LCASE(?voornaam)  # Sorteert de resultaten op achternaam, daarna voornaam (hoofdletterongevoelig)

Probeer het!