Tutorial/fr

1. Introduction à SPARQL

Utiliser SPARQL, c’est comme être un⸱e enquêteur⸱rice dans un vaste fonds d’archives. Ici, plutôt que de fouiller chaque document un par un, vous disposez d’un langage qui vous permet, en une requête précise, de retrouver instantanément les informations correspondant à vos critères.

Dans le cadre de Resistance in Belgium, SPARQL facilite l’accès aux données sur les résistant⸱e⸱s : lieu de naissance, domicile, statuts de reconnaissance officiels ou appartenance à une organisation de résistance.

Avec SPARQL, vous pouvez :

• Filtrer et croiser des informations ;
• Personnaliser vos recherches avec des critères spécifiques ;
• Extraire des données précises sans parcourir des milliers de fiches manuellement ;
• Générer des visualisations pour mieux interpréter vos résultats.

Cette approche vous offre une autonomie précieuse dans l’analyse des données de Resistance in Belgium. Vous pouvez non seulement extraire des listes de noms, mais aussi identifier des liens complexes, comme des résistant⸱e⸱s affilié⸱e⸱s à plusieurs organisations ou ayant obtenu différents statuts de reconnaissance.

SPARQL vous donne le superpouvoir convoité par tous les chercheurs et chercheuses : poser une question ultra-précise et voir les réponses surgir en quelques millisecondes. Bien sûr, comme tout superpouvoir, il demande un peu d’entraînement pour être maîtrisé. Mais pas de panique ! Ce tutoriel est là pour vous guider et transformer les obstacles en opportunités… Qui a dit que la recherche dans les archives devait être poussiéreuse ?

Prêt⸱e à maîtriser la force de SPARQL ? Allons-y !

2. Stratégie pour vos premières requêtes

Maintenant que vous avez une idée générale de ce qu’est SPARQL, voici une stratégie pour bien démarrer vos recherches.

Il existe des outils d’aide à la rédaction de requêtes SPARQL, mais pour gagner en autonomie et en flexibilité, il est souvent plus efficace de partir d’une requête existante et de l’adapter à vos besoins spécifiques.

Cette approche vous permet de :

• Consulter nos exemples de requêtes SPARQL ;
• Utiliser des outils d’intelligence artificielle capables de générer des requêtes selon vos besoins.

Ce tutoriel vous guidera dans la compréhension des bases de SPARQL et vous apprendra à identifier les éléments clés pour adapter une requête existante avec succès.

3. Les bases d’une requête SPARQL

Une requête SPARQL repose sur quelques éléments essentiels. Voici les deux principaux :

• SELECT : cette clause permet de choisir quelles informations afficher dans les résultats. Vous spécifiez ici les éléments que vous souhaitez voir apparaître.
• WHERE : cette clause permet de filtrer les données en définissant des critères précis. C’est ici que vous décrivez les conditions que les données doivent respecter.

📝 Exemple simple

Voici une requête qui extrait les noms et prénoms des personnes présentes dans la base de données. Les lignes qui commencent par # sont des commentaires pour expliquer chaque partie de la requête.

SELECT ?nom ?prenom
WHERE {
  ?personne wdt:P1 wd:Q2 ;     # Sélectionne des personnes
            wdt:P3 ?nom ;      # Récupère le nom de famille
            wdt:P2 ?prenom .   # Récupère le prénom
}

Explication de l’exemple :

1. SELECT ?nom ?prenom :
   Indique que l’on souhaite voir apparaître les valeurs des variables ?nom et ?prenom dans les résultats.
2. WHERE { ... } :
   Décrit la structure et les conditions de la requête :
   • ?personne wdt:P1 wd:Q2 : sélectionne les éléments qui sont des êtres humains (P1 = nature de l’élément, Q2 = personne).
   • wdt:P3 ?nom : associe à ?nom le nom de famille de la personne (P3).
   • wdt:P2 ?prenom : associe à ?prenom le prénom de la personne (P2).

Vous connaissez maintenant les bases de toutes les requêtes SPARQL. Vous allez pouvoir les adapter à vos besoins en sélectionnant facilement les variables à utiliser et en ajoutant des filtres, des colonnes supplémentaires ou des options avancées.

4. L’astuce qui fait toute la différence

Lorsque vous rédigez une requête SPARQL, il peut être fastidieux de se souvenir des identifiants numériques pour les communes, statuts de reconnaissance ou organisations de résistance. Heureusement, une fonctionnalité d’auto-complétion est disponible pour vous simplifier la tâche.

• Astuce pratique : appuyez sur Ctrl + Espace lorsque vous êtes en train de taper une propriété ou une valeur. Cela vous permet de rechercher des termes dans votre langue plutôt que d’utiliser des identifiants numériques.

Exemple :
Si vous cherchez une commune comme Anderlecht, au lieu de retenir son identifiant (par exemple wd:Q102), utilisez Ctrl + Espace et commencez à taper "Anderlecht" pour que l’éditeur propose automatiquement l’identifiant correspondant.

Cette méthode vous permet de gagner du temps et d’éviter les erreurs liées à la saisie des identifiants.

Auto-complétion en action — Appuyez sur Ctrl + Espace pour trouver la bonne propriété ou valeur.

5. Afficher les labels dans la langue de son choix

Lorsque vous interrogez une base de données Wikibase avec SPARQL, les résultats peuvent parfois afficher des identifiants (par exemple Q102) au lieu de textes explicites (par exemple : Anderlecht). Pour rendre les résultats plus lisibles, vous pouvez récupérer les labels (libellés) dans la langue de votre choix (français, néerlandais, allemand ou anglais). Il suffit d’utiliser SERVICE wikibase:label en fin de requête pour récupérer les intitulés dans la langue de votre choix.

Comment faire ?
Ajoutez le service wikibase:label à votre requête pour afficher les labels. Voici un exemple de requête simple qui récupère le nom des personnes avec leur domicile, en affichant les “labels” en français :

SELECT ?personne ?personneLabel ?Domicile ?DomicileLabel
WHERE {
  ?personne wdt:P1 wd:Q2.         # Sélectionner des êtres humains
  ?personne wdt:P7 wd:Q102.       # Domicile (P7) = Anderlecht (Q102)
  SERVICE wikibase:label {        # Service pour récupérer les labels
    bd:serviceParam wikibase:language "fr". # Langue choisie : français
  }
}

Explication rapide

• SERVICE wikibase:label : active le service pour récupérer les labels.
• bd:serviceParam wikibase:language "fr" : définit la langue des labels (changez "fr" pour "en", "nl", "de" selon vos besoins).

Utiliser AUTO_LANGUAGE
Pour que les labels s’affichent automatiquement dans la langue définie par votre navigateur ou votre préférence utilisateur, utilisez AUTO_LANGUAGE :

bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".

Astuces

• Pour que les labels s’affichent automatiquement dans la langue définie par votre navigateur ou votre préférence utilisateur, utilisez bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr,en".
• Vous pouvez aussi utiliser plusieurs langues en priorité. Par exemple, pour afficher les labels en français, et si indisponible, en anglais : bd:serviceParam wikibase:language "fr,en,[AUTO_LANGUAGE]"

6. Ajouter des informations supplémentaires

Pour enrichir vos résultats, vous pouvez ajouter plusieurs colonnes contenant des informations supplémentaires, comme le domicile, la date de naissance ou d'autres détails pertinents. Pour vous inspirer : consulter la liste des propriétés ou observer comment sont modélisées les données à l’aide d’un exemple, ici Andrée De Jongh.

Ajouter des colonnes simples
Il suffit d'ajouter les propriétés correspondant aux informations que vous souhaitez extraire.

Exemple : ajouter le domicile et la date de naissance des personnes.

SELECT ?personne ?personneLabel ?domicileLabel ?dateNaissance
WHERE {
  ?personne wdt:P7 ?domicile .        # P7 : Domicile
  ?personne wdt:P67 ?dateNaissance .  # P67 : Date de naissance

    SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr" }
}

Rendre une colonne optionnelle avec OPTIONAL
Si certaines informations peuvent être manquantes, utilisez OPTIONAL pour éviter que cela restreigne le nombre de résultats. Ajouter OPTIONAL permet de récupérer des résultats même si une des colonnes est vide.

Exemple : ajouter la date de naissance seulement si l'information est disponible.

SELECT ?personne ?personneLabel ?domicileLabel ?dateNaissance
WHERE {
  ?personne wdt:P7 ?domicile .                    # P7 : Domicile

   OPTIONAL { ?personne wdt:P67 ?dateNaissance . } # P67 : Date de naissance (facultatif)

  SERVICE wikibase:label { bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr" }
}

Astuce : pour combiner plusieurs valeurs en une seule colonne (par exemple, “concaténer” l’appartenance à différentes organisations de résistance), utilisez CONCAT. Cela permet de regrouper ces informations dans une même cellule tout en conservant une seule ligne par personne. Pour explorer cette fonction et ses variantes, nous vous encourageons à consulter la documentation SPARQL disponible en ligne.

7. Limiter le nombre de résultats

Pour restreindre le nombre de résultats affichés (notamment si vous voulez tester une requête contenant un très grand nombre de colonnes), ajoutez LIMIT à votre requête.

Exemple : afficher uniquement les 10 premiers résultats.

SELECT ?personne ?personneLabel ?dateNaissance
WHERE {
  ?personne wdt:P67 ?dateNaissance .

    SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr"
  }
}
LIMIT 10

8. Ordonner les résultats

Pour trier les résultats selon une certaine colonne, utilisez ORDER BY. Par défaut, le tri est ascendant (ASC), mais vous pouvez aussi spécifier un tri descendant (DESC).

Exemple : Trier les résultats par date de naissance croissante.

SELECT ?personne ?personneLabel ?dateNaissance
WHERE {
  ?personne wdt:P67 ?dateNaissance .

    SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr"
  }
}
ORDER BY ASC(?dateNaissance)

9. Ajouter des filtres

Les filtres permettent d’affiner vos résultats en ajoutant des critères spécifiques à votre requête. Ils sont utiles pour combiner plusieurs conditions ou exclure certaines valeurs.

📝 Exemple simple sans filtre

Pour sélectionner les personnes répondant à un certain critère, comme par exemple “domiciliées dans à Anderlecht”, vous pouvez écrire directement :

?personne wdt:P4 wd:Q102 .  # Sélectionne les personnes domiciliées à Anderlecht

Utiliser FILTER pour des conditions spécifiques
Lorsque vous souhaitez affiner davantage vos résultats, utilisez FILTER. Cela vous permet de combiner plusieurs conditions, par exemple : sélectionner les personnes domiciliées à Anderlecht et nées après le 1er janvier 1920 (Lien pour tester la requête).

SELECT ?personne ?personneLabel ?domicileLabel ?dateNaissance
WHERE {
  # Sélectionner le domicile et la date de naissance de la personne
  ?personne wdt:P7 ?domicile .        # P7 : Domicile
  ?personne wdt:P67 ?dateNaissance .  # P67 : Date de naissance

    # Filtrer pour les personnes domiciliées à Anderlecht (wd:Q102) et nées après le 1er janvier 1920
  FILTER(?domicile = wd:Q102 && ?dateNaissance >= "1920-01-01T00:00:00Z"^^xsd:dateTime)

    # Utiliser le service pour récupérer les libellés lisibles dans la langue choisie
  SERVICE wikibase:label {
    bd:serviceParam wikibase:language "[AUTO_LANGUAGE],fr"
  }
}

Usage avancé : Il est également possible d’utiliser FILTER NOT EXISTS pour des exclusions plus complexes. Cette option permet de filtrer les résultats en excluant ceux pour lesquels une certaine condition existe. Vous pourrez explorer cette fonctionnalité dans des ressources avancées sur SPARQL.

10. Visualiser vos résultats

Pour créer des graphiques à partir de vos requêtes SPARQL, vous avez deux options :

• Utiliser les fonctionnalités du Query Service : visualiser les données sous forme de tableurs, cartes, graphiques à barres, et chronologies. Pour en savoir plus, consultez la documentation de Wikidata.
• Exporter les données et utiliser d’autres outils : vous pouvez exporter vos résultats au format CSV ou TSV, puis les traiter avec des outils de visualisation de données.

11. Requêtes fédérées

Fonctionnalité avancée : Si vous souhaitez interroger plusieurs bases de données simultanément pour enrichir vos résultats, vous pouvez utiliser des requêtes fédérée cet exemple mis à votre disposition, qui permet d'extraire des informations de Resistance in Belgium tout en les combinant avec des données provenant de sources externes (ici : Wikidata).

12. Sauvegarder et partager vos requêtes

Après avoir exécuté une requête SPARQL, vous pouvez sauvegarder et partager son lien. Cliquez sur l’onglet “Lien” au-dessus des résultats pour générer une Tiny URL (un lien court) facile à copier et à transmettre. Cela permet à d’autres utilisateurs d’exécuter directement la même requête sans effort.

13. Télécharger les résultats

Après avoir exécuté une requête, utilisez l’onglet “Télécharger” (situé à droite au-dessus des résultats) pour exporter les données dans différents formats : CSV (compatible avec LibreOffice Calc ou Excel), TSV ou JSON.

Bonnes pratiques : enregistrez le fichier avec un nom clair qui précise les critères de recherche pour faciliter sa réutilisation.

14. Ressources supplémentaires

Pour approfondir vos connaissances et créer des requêtes plus complexes, voici quelques ressources utiles :

• Liste des propriétés utilisées pour décrire les résistant⸱e⸱s :
  https://data.arch.be/wiki/Special:ListProperties
• Fiche "type" d'une personne (exemple : Andrée De Jongh) :
  https://data.arch.be/wiki/Item:Q6793
• Échantillon de neuf requêtes SPARQL, réparties en trois niveaux de complexité :
  https://data.arch.be/wiki/In-depth_search/fr
• FAQ pour comprendre le contexte et le contenu des données disponibles :
  https://data.arch.be/wiki/FAQ/fr

Ressources externes
Nous vous encourageons également à consulter des ressources externes, telles que les tutoriels Wikidata, qui offrent une excellente introduction aux requêtes SPARQL. Bien que ces exemples utilisent le même logiciel (Wikibase) que notre projet, notez que les données et la structure des requêtes sont spécifiques à Wikidata et ne s'appliquent pas directement au contenu de Resistance in Belgium.

• Wikidata Query Service Tutorial (interactive) : un tutoriel interactif pour débutants qui permet d'explorer les requêtes SPARQL de manière pratique (ressource en anglais).
• Une introduction en douceur au service de requête de Wikidata : un guide simple étape par étape pour comprendre l'interface et créer des requêtes.
• Wikidata:Tutoriel SPARQL : un guide SPARQL détaillé et structuré pour ceux qui souhaitent approfondir la rédaction de requêtes.
• Outils d'intelligence artificielle capables de vous assister dans la rédaction de requêtes.